#!/usr/bin/env gnuplot
# Plasma Optics of Electron Gas
# 2004-06-25   NISHIMATSU Takeshi
#
#  At #1# below, the dielectric function epsilon(omega) of the
# electron gas is plotted as a function of frequency omega. (See
# C. Kittel: "Introduction to Solid State Physics" 7th edition
# Chap. 10.)
#
# PROBLEM
# a) Plot real and imaginary parts of the complex refractive index
#           N(omega) = epsilon(omega)**0.5
#   at #2# below. Assume that epsilon(inf)=20.0.
# b) Explain why the reflectivity coefficient r(omega) can be
#   written with N(omega) as
#                       N(omega) - 1
#           r(omega) = -------------- .
#                       N(omega) + 1
# c) Plot the reflectance R(omega) = |r(omega)|**2 at #3# below.
# d) Compare the 3rd plot with Fig. 8 in W. G. Spitzer and
#   H.Y. Fan: Phys. Rev. vol.106 (1957) pp.882-890.
# e) Around omega/omega_p = 1+, Re(N(omega)) becomes less than
#   unity! Is it OK?
#
# How to execute this script:
#  execute% gnuplot reflectance.gp
#  preview% gv reflectance.ps
#  print  % lpr reflectance.ps
##
set terminal postscript portrait enhanced color solid 22
set output "reflectance.ps"
set multiplot

e_inf=20.0
epsilon(x)=e_inf*(1.0-1.0/x**2)

set grid
set lmargin 9
set format x "%.1f"
set format y "%.1f"
set xrange [0:2.2]
set size 1.0,0.333

set origin 0.0,0.667
set title 'Plasma Optics of Electron Gas   {/Symbol e(\245)=20.0}'
set nokey
set ylabel '{/Symbol e(w)/e(\245)}'
set yrange [-2:1]
#1#
plot epsilon(x)/e_inf lw 3

set origin 0.0,0.333
set notitle
set key 0.7, 2.0 samplen 1
set ylabel "complex refractive\n index {/Times-Italic N}{/Symbol (w)}"
set yrange [0:5]
#2#
plot imag(exp(sqrt(-1)*x)**0.5) title 'Im({/Times-Italic N}{/Symbol (w)})' lw 3,\
     real(exp(sqrt(-1)*x)**0.5) title 'Re({/Times-Italic N}{/Symbol (w)})' lw 3

set origin 0,0
set nokey
set xlabel '{/Symbol w /w}_p'
set ylabel 'Reflectance'
set yrange [0:1.01]
#3#
plot abs(x-1) lw 3